Arduino Hacking Tools: War Driving

The Code:

To use the D1-Mini, you need to have the ESP8266 boards manager installed to your Arduino IDE, if you need to, you can follow our guide on setting up the D1-Mini here: D1-Mini Setup Guide

You will need to have the following libraries installed:

• TinyGPSPlus
• ESP8266WiFi
• SD

If you need help installing libraries, you can read our guide here: How to install Arduino Libraries

/**************************************************************************
 *                  tinyWARMACHINE Modified by Meganano                   *
 *  War Driving Arduino Wi-Fi Access Point Scanner with GPS Coordinates   *
 **************************************************************************
 IDE Board Settings:
 boards manager : LOLIN(WEMOS)D1 R2 & mini
 upload speed   : 921600
 cpu frequency  : 160mhz
 ***************************************************************************/

#include <TinyGPS++.h>
#include <SoftwareSerial.h>
#include <ESP8266WiFi.h>
#include <SD.h>

#define SD_CS      D8
SoftwareSerial serial_connection(D4, D3); // tx,rx
TinyGPSPlus gps;

String logFileName = "";
int networks = 0;
int LOG_RATE = 1000;
//int blank=D2;


void initializeSD() {
  Serial.println("Creating Log File");
  int i = 0;
  logFileName = "log0.txt";
  while (SD.exists(logFileName)) {
    i++; logFileName = "log" + String(i) + ".txt";
  }
  File logFile = SD.open(logFileName, FILE_WRITE);
  if (logFile) {
    Serial.println("Log File Created");
    logFile.println("WarDriving Report");
    logFile.close();
  }
}


void setup() {
  Serial.begin(9600);
  serial_connection.begin(9600);
  Serial.println("GPS Starting");
  delay(30000);
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  
  while (!SD.begin(SD_CS)) {
    Serial.println("SD Not Found");
  }
  Serial.println("SD Found");
  initializeSD();
  delay(500);
  Serial.println("tinyWARMACHINE Started");
}

String getEncryption(uint8_t network, String src) { // return encryption for WiGLE or print
  byte encryption = WiFi.encryptionType(network);
  switch (encryption) {
    case 2:
      if (src == "screen") {
        return "WPA";
      }
      return "[WPA-PSK-CCMP+TKIP][ESS]";
    case 5:
      if (src == "screen") {
        return "WEP";
      }
      return "[WEP][ESS]";
    case 4:
      if (src == "screen") {
        return "WPA2";
      }
      return "[WPA2-PSK-CCMP+TKIP][ESS]";
    case 7:
      if (src == "screen") {
        return "NONE" ;
      }
      return "[ESS]";
    case 8:
      if (src == "screen") {
        return "AUTO";
      }
      return "[WPA-PSK-CCMP+TKIP][WPA2-PSK-CCMP+TKIP][ESS]";
    default:
      return "?";;
  }
}

void loop() {
  //Start Wi-Fi Scan
  WiFi.disconnect();
  delay(100);
  int n = WiFi.scanNetworks();
  if (n == 0){
    Serial.println("No Networks Found");
  }else{
    File logFile = SD.open(logFileName, FILE_WRITE); 
    logFile.println("");
    logFile.print(n);
    logFile.println(" Networks Found");
    Serial.print(n);
    Serial.println(" Networks Found");
    for (int i = 0; i < n; ++i) {
      Serial.print(i + 1);
      Serial.print(": ");
      Serial.print("SSID: "); Serial.print(WiFi.SSID(i));
      Serial.print(" | Channel: "); Serial.print(WiFi.channel(i));
      Serial.print(" | Strength: "); Serial.print(WiFi.RSSI(i));
      Serial.print(" | MAC: "); Serial.print(WiFi.BSSIDstr(i));
      Serial.print(" | Security: "); Serial.print(getEncryption(i, ""));
      Serial.print((WiFi.encryptionType(i) == ENC_TYPE_NONE) ? " Unsecured" : " Secured");
          
      //Log Wi-Fi Data       
      logFile.print(i + 1); logFile.print(": ");
      logFile.print("SSID: "); logFile.print(WiFi.SSID(i));
      logFile.print(" | Channel:"); logFile.print(WiFi.channel(i));
      logFile.print(" | Strength:"); logFile.print(WiFi.RSSI(i));
      logFile.print(" | MAC:"); logFile.print(WiFi.BSSIDstr(i));
      logFile.print(" | Security:"); logFile.print(getEncryption(i, ""));
      logFile.print((WiFi.encryptionType(i) == ENC_TYPE_NONE) ? " Unsecured" : " Secured");
      //Start GPS Scan
      while(serial_connection.available()){
        gps.encode(serial_connection.read());
      }  
      Serial.print(" | Longitude: "); Serial.print(gps.location.lng(), 6);
      Serial.print(" | Latitude: "); Serial.print(gps.location.lat(), 6);
      Serial.println("");
      //Log GPS Data
      logFile.print(" | Longitude:"); logFile.print(gps.location.lng(), 6);
      logFile.print(" | Latitude:"); logFile.print(gps.location.lat(), 6);
      logFile.println("");  
    } 
    logFile.close();  
    delay(LOG_RATE);
  }
}